0 комментариев на «“botanicalls.com — цветок напоминает о поливе через Twitter”»

1. из идей улучшения — полностью беспроводное решение
   например, устройство полностью встроено в горшок, получает энергию от маленьких солнечных батареек и соединялось с интерентом через wi-fi 🙂

   Войдите, чтобы ответить

2. А есть какая нибудь информация как они измеряют влажность земли? очень интересно
   Сам могу предположить что меряя сопротивление земли, но мне кажеться есть более умный способ

   Войдите, чтобы ответить

   • здесь, всё же, замеряется сопротивление
     http://www.botanicalls.com/kits/customize/
     вот функция из проекта:

     
     //function for checking soil moisture against threshold
     void moistureCheck() {
       static int counter = 1;//init static counter
       int moistAverage = 0; // init soil moisture average
       if((millis() - lastMoistTime) / 1000 > (MOIST_SAMPLE_INTERVAL / MOIST_SAMPLES)) {
         for(int i = MOIST_SAMPLES - 1; i > 0; i--) {
           moistValues[i] = moistValues[i-1]; //move the first measurement to be the second one, and so forth until we reach the end of the array.   
         }
         digitalWrite(PROBEPOWER, HIGH);
         moistValues[0] = analogRead(MOISTPIN);//take a measurement and put it in the first place
         digitalWrite(PROBEPOWER, LOW);
         lastMoistTime = millis();
         int moistTotal = 0;//create a little local int for an average of the moistValues array
         for(int i = 0; i < MOIST_SAMPLES; i++) {//average the measurements (but not the 0s)
           moistTotal += moistValues[i];//in order to make the average we need to add them first 
         }
         if(counter<MOIST_SAMPLES) {
           moistAverage = moistTotal/counter;
           counter++; //this will add to the counter each time we've gone through the function
         }
         else {
           moistAverage = moistTotal/MOIST_SAMPLES;//here we are taking the total of the current light readings and finding the average by dividing by the array size
         } 
         //lastMeasure = millis();
         Serial.print("moist: ");
         Serial.println(moistAverage,DEC); 
     
         ///return values
         if ((moistAverage < DRY)  &&  (lastMoistAvg >= DRY)  &&  (millis() > (lastTwitterTime + TWITTER_INTERVAL)) ) {
           uint8_t response = posttweet("URGENT! Water me!");   // announce to Twitter
           notify(response); 
         }
         else if  ((moistAverage < MOIST)  &&  (lastMoistAvg >= MOIST)  &&  (millis() > (lastTwitterTime + TWITTER_INTERVAL)) ) {
           uint8_t response = posttweet("Water me please.");   // announce to Twitter
           notify(response); 
         }
         lastMoistAvg = moistAverage; // record this moisture average for comparision the next time this function is called
         moistLight(moistAverage);
       }
     }